Schwartz Personal Values Scale

The scale

The 57 items versions

For other languages, I recommend you contact Shalom Schwartz.

The list of values:

  1. EQUALITY (equal opportunity for all)
  2. INNER HARMONY (at peace with myself)
  3. SOCIAL POWER (control over others, dominance)
  4. PLEASURE (gratification of desires)
  5. FREEDOM (freedom of action and thought)
  6. A SPIRITUAL LIFE (emphasis on spiritual not material matters)
  7. SENSE OF BELONGING (feeling that others care about me)
  8. SOCIAL ORDER (stability of society)
  9. AN EXCITING LIFE (stimulating experiences)
  10. MEANING IN LIFE (a purpose in life)
  11. POLITENESS (courtesy, good manners)
  12. WEALTH (material possessions, money)
  13. NATIONAL SECURITY (protection of my nation from enemies)
  14. SELF RESPECT (belief in one's own worth)
  15. RECIPROCATION OF FAVORS (avoidance of indebtedness)
  16. CREATIVITY (uniqueness, imagination)
  17. A WORLD AT PEACE (free of war and conflict)
  18. RESPECT FOR TRADITION (preservation of time honored customs)
  19. MATURE LOVE (deep emotional & spiritual intimacy)
  20. SELF DISCIPLINE (self restraint, resistance to temptation)
  21. PRIVACY (the right to have a private sphere)
  22. FAMILY SECURITY (safety for loved ones)
  23. SOCIAL RECOGNITION (respect, approval by others)
  24. UNITY WITH NATURE (fitting into nature)
  25. A VARIED LIFE (filled with challenge, novelty and change)
  26. WISDOM (a mature understanding of life)
  27. AUTHORITY (the right to lead or command)
  28. TRUE FRIENDSHIP (close, supportive friends)
  29. A WORLD OF BEAUTY (beauty of nature and the arts)
  30. SOCIAL JUSTICE (correcting injustice, care for the weak)
  31. INDEPENDENT (self reliant, self sufficient)
  32. MODERATE (avoiding extremes of feeling & action)
  33. LOYAL (faithful to my friends, group)
  34. AMBITIOUS (hard working, aspiring)
  35. BROADMINDED (tolerant of different ideas and beliefs)
  36. HUMBLE (modest, self effacing)
  37. DARING (seeking adventure, risk)
  38. PROTECTING THE ENVIRONMENT (preserving nature)
  39. INFLUENTIAL (having an impact on people and events)
  40. HONORING OF PARENTS AND ELDERS (showing respect)
  41. CHOOSING OWN GOALS (selecting own purposes)
  42. HEALTHY (not being sick physically or mentally)
  43. CAPABLE (competent, effective, efficient)
  44. ACCEPTING MY PORTION IN LIFE (submitting to life's circumstances)
  45. HONEST (genuine, sincere)
  46. PRESERVING MY PUBLIC IMAGE (protecting my “face”)
  47. OBEDIENT (dutiful, meeting obligations)
  48. INTELLIGENT (logical, thinking)
  49. HELPFUL (working for the welfare of others)
  50. ENJOYING LIFE (enjoying food, sex, leisure, etc.)
  51. DEVOUT (holding to religious faith & belief)
  52. RESPONSIBLE (dependable, reliable)
  53. CURIOUS (interested in everything, exploring)
  54. FORGIVING (willing to pardon others)
  55. SUCCESSFUL (achieving goals)
  56. CLEAN (neat, tidy)
  57. SELF-INDULGENT (doing pleasant things)
  58. (Some versions also have – 58 - OBSERVING SOCIAL NORMS (to maintain face))

Scale:

  • -1 - Opposed to my values
  • 0 - Not important
  • 6 - Very important
  • 7 - Of supreme importance

Coding

  • Power = 3, 12, 27
  • Achievement = 34, 43, 55, 39
  • Hedonism = 4, 50, 57
  • Stimulation = 9, 25, 37
  • Selfdirection = 5, 16, 31, 41, 53
  • Universalism = 1, 17, 24, 26, 29, 30, 35, 38
  • Benevolence = 33, 45, 49, 52, 54
  • Tradition = 36, 44, 51, 32
  • Conformity = 11, 20, 40, 47
  • Security = 13, 15, 56, 8, 22

SPSS Syntax

This syntax is used for cleaning up and calculating Schwartz Values Scale (57 items) data based on the 2009 draft manual.

*****************
**    VALUES   **
*****************

** counting ratings to exclude participants. exclude participants that used 7 more than 21 times, and those that used any other rating more than 35 times

count countneg1 = svs1 to svs57 (-1).
count count0 = svs1 to svs57 (0).
count count1 = svs1 to svs57 (1).
count count2 = svs1 to svs57 (2).
count count3 = svs1 to svs57 (3).
count count4 = svs1 to svs57 (4).
count count5 = svs1 to svs57 (5).
count count6 = svs1 to svs57 (6).
count count7 = svs1 to svs57 (7).
count count8 = svs1 to svs57 (SYSMIS).

do IF (count0 ge 35 OR count1 GE 35 OR count2 GE 35 OR count3 GE 35 OR count4 GE 35
        OR count5 GE 35 OR count6 GE 35 OR count7 GE 21 OR count8 GE 15 or countneg1 ge 35).
compute i=1 .
else .
compute i=2.
end if.
freq var=i.
exe.
select if (i=2).
exe.

USE ALL.
COMPUTE filter_$=(i=2).
VARIABLE LABELS filter_$ 'i=2 (FILTER)'.
VALUE LABELS filter_$ 0 'Not Selected' 1 'Selected'.
FORMATS filter_$ (f1.0).
FILTER BY filter_$.
EXECUTE.


** computing indexes of value types. These will be used in regressions ***

compute po = mean(svs3,svs12,svs27).
compute ac = mean(svs34,svs43,svs55,svs39).
compute he = mean(svs4,svs50,svs57)        .
compute st = mean(svs9,svs25,svs37)         .
compute sd = mean(svs5,svs16,svs31,svs41,svs53)  .
compute un = mean(svs1,svs17,svs24,svs26,svs29,svs30,svs35,svs38)   .
compute be = mean(svs33,svs45,svs49,svs52,svs54).
compute tr = mean(svs36,svs44,svs51,svs32,svs18).
compute co = mean(svs11,svs20,svs40,svs47)       .
compute se = mean(svs13,svs15,svs56,svs8,svs22)         .
compute open=mean (sd, st).
compute selfenh=mean (he, ac, po).
compute selftran=mean (un, be). 
compute conserv=mean (tr, co, se).

compute mrat = mean(svs1 to svs57).


DO REPEAT  s = svs1 TO svs57 /
  t = t1 TO t57    .
COMPUTE t = (s - mrat).
END REPEAT             .

** Centered value types. These will be used in all analyses but regressions

compute tpo = mean(t3,t12,t27).
compute tac = mean(t34,t43,t55,t39).
compute the = mean(t4,t50,t57).
compute tst = mean(t9,t25,t37).
compute tsd = mean(t5,t16,t31,t41,t53).
compute tun = mean(t1,t17,t24,t26,t29,t30,t35,t38).
compute tbe = mean(t33,t45,t49,t52,t54).
compute ttr = mean(t36,t44,t51,t32,t18).
compute tco = mean(t11,t20,t40,t47).
compute tse = mean(t13,t15,t56,t8,t22).
compute topen=mean (tsd, tst).
compute tselfenh=mean (the, tac, tpo).
compute tselftran=mean (tun, tbe). 
compute tconserv=mean (ttr, tco, tse).

RELIABILITY
  /VARIABLES= svs3,svs12,svs27
  /FORMAT=NOLABELS
  /SCALE(power )=ALL/MODEL=ALPHA.
RELIABILITY
  /VARIABLES= svs34,svs43,svs55,svs39
  /FORMAT=NOLABELS
  /SCALE(achiev )=ALL/MODEL=ALPHA.
RELIABILITY
  /VARIABLES=svs4,svs50,svs57        
  /FORMAT=NOLABELS
  /SCALE(hedonism  )=ALL/MODEL=ALPHA.
RELIABILITY
  /VARIABLES=svs9,svs25,svs37         
  /FORMAT=NOLABELS
  /SCALE(stimul  )=ALL/MODEL=ALPHA.
RELIABILITY
  /VARIABLES=svs5,svs16,svs31,svs41,svs53  
  /FORMAT=NOLABELS
  /SCALE(selfdir )=ALL/MODEL=ALPHA.
RELIABILITY
  /VARIABLES=svs1,svs17,svs24,svs26,svs29,svs30,svs35,svs38
  /FORMAT=NOLABELS
  /SCALE(univer )=ALL/MODEL=ALPHA.
RELIABILITY
  /VARIABLES=svs33,svs45,svs49,svs52,svs54
  /FORMAT=NOLABELS
  /SCALE(benev )=ALL/MODEL=ALPHA.
RELIABILITY
  /VARIABLES=svs36,svs44,svs51,svs32,svs18
  /FORMAT=NOLABELS
  /SCALE(trad)=ALL/MODEL=ALPHA.
RELIABILITY
  /VARIABLES= svs11,svs20,svs40,svs47
  /FORMAT=NOLABELS
  /SCALE(conform )=ALL/MODEL=ALPHA.
RELIABILITY
  /VARIABLES=svs13,svs15,svs56,svs8,svs22
  /FORMAT=NOLABELS
  /SCALE(secu )=ALL/MODEL=ALPHA..
RELIABILITY
  /VARIABLES= svs3,svs12,svs27, svs34,svs43,svs55,svs39, svs4,svs50,svs57
  /FORMAT=NOLABELS
  /SCALE(selfenh )=ALL/MODEL=ALPHA..
RELIABILITY
  /VARIABLES=svs1,svs17,svs24,svs26,svs29,svs30,svs35,svs38, svs33,svs45,svs49,svs52,svs54
  /FORMAT=NOLABELS
  /SCALE(selftrans )=ALL/MODEL=ALPHA..
RELIABILITY
  /VARIABLES=svs36,svs44,svs51,svs32,svs18,  svs11,svs20,svs40,svs47, svs13,svs15,svs56,svs8,svs22
  /FORMAT=NOLABELS
  /SCALE(conserv )=ALL/MODEL=ALPHA..
RELIABILITY
  /VARIABLES=svs9,svs25,svs37, svs5,svs16,svs31,svs41,svs53
  /FORMAT=NOLABELS
  /SCALE(openchan )=ALL/MODEL=ALPHA..
  
VARIABLE LABELS
po "PowerR"
ac "AchievementR"
he "HedonismR"
st "StimulationR"
sd "Self DirectionR"
un "UniversalismR"
be "BenevolenceR"
tr "TraditionR"
co "ConformityR"
se "SecurityR"
open "Openness to ChangeR"
selfenh "Self EnhancementR"
selftran "Self TranscendenceR"
conserv "ConservationR"
tpo "Power"
tac "Achievement"
the "Hedonism"
tst "Stimulation"
tsd "Self Direction"
tun "Universalism"
tbe "Benevolence"
ttr "Tradition"
tco "Conformity"
tse "Security"
topen "Openness to Change"
tselfenh "Self Enhancement"
tselftran "Self Transcendence"
tconserv "Conservation".
schwartz_values_scale_svs.txt · Last modified: 2017/07/12 03:51 by filination
CC Attribution-Noncommercial-Share Alike 4.0 International
Driven by DokuWiki Recent changes RSS feed Valid CSS Valid XHTML 1.0